gausel.bas

100 ' Program gausel

110 'ガウスの消去法による連立方程式の解法

120 ' 別な方程式を解く場合は， N の値を変更し，新しい係数と

130 ' 非同次ベクトルの値でデータ文を置き換える。

140 ' DIM文はとくに変更する必要はない。

147 ' 係数行列　　p.52 演習2

150 DATA 2, 1

160 DATA 1, 3

170 ' 非同次ベクトル

180 DATA 4, 7

190 N=2

200 DIM A(30,30),X(30),Y(30)

210 FOR I=1 TO N

220   FOR J=1 TO N

230     READ A(I,J)

240   NEXT J

245 NEXT I

250 FOR I=1 TO N

260   READ Y(I)

270 NEXT I

280 '

290 FOR I=1 TO N-1

300   L=I+1

310   FOR J=L TO N

320     IF A(J,I)=0 THEN GOTO 380

330     FOR K=L TO N

340       A(J,K) = A(J,K) - A(I,K)*A(J,I)/A(I,I)

350     NEXT K

360     Y(J) = Y(J) - Y(I)*A(J,I)/A(I,I)

370   NEXT J

375 NEXT I

380 X(N)=Y(N)/A(N,N)

390 PRINT "No.";N, X(N)

400 FOR I=1 TO N-1

410   K = N-I

420   L = K+1

430   FOR J=L TO N

440     Y(K) = Y(K) - X(J)*A(K,J)

450   NEXT J

460   X(K) = Y(K)/A(K,K)

470   PRINT "No.";K, X(K)

480 NEXT I

490 END

問題　Mo、TiおよびVイオンのそれぞれの溶液と過酸化水素とで錯体を作り、可視領域の吸収
スペクトルを測定した。330nm、410nmおよび460nmにおけるそれぞれの金属錯体の吸光度
は次のとおりであった。溶液の濃度はすべて40.0 mg/l である。

150 DATA 10.4, 3.25, 0.0

160 DATA 1.2, 15.2, 3.7

170 DATA .05,10.25, 5.0

175 ' 非同次ベクトル

180 DATA .284, .857, .718 

190 N=3

Mo、TiおよびVイオンを含む未知の溶液を過酸化水素で処理し、波長330nm、410nmおよび
460nmにおける吸光度を測定したところ、｛0.284, 0.857, 0.718｝となった。それぞれの金属イオンの
濃度を求めなさい。

係数行列Aが上三角行列となるように変換し、Bベクトルにも同じ操作を施す。最後の式は
未知数x_nのみを含みx_nについて解くことができる。結果を順次上の式に代入していくことに
より解をすべて得ることができる。

No. 3	V	0.0604
No. 2	Ti	0.0405
No. 1	Mo	0.0146

	Mo	Ti	V
330nm	0.416	0.130	0.000
410nm	0.048	0.608	0.148
460nm	0.002	0.410	0.200

Gaussの消去法（連立方程式の解法）

gausel.bas