線形最小自乗法
ランダムな実験誤差を含むデータの集合（xi, yi）について、一次式 y =mx + b による最小自乗法に
よる当てはめを行うと、傾き m および切片 b は次のように与えられる
問題 鋭敏な温度計を取り付けたDewarフラスコ中の氷酢酸に無水フッ化カリウムを加え、温度変化を
測定することにより、種々の濃度におけるフッ化カリウムの溶解熱を測定した。フラスコと内容の熱容量は
4.168KJK-1であるとして、それぞれの濃度における溶質1モルあたりの溶解エンタルピーを計算し、最小
自乗法によるカーブフィッティングを行いなさい。 J. Emsley, J Chem Soc.,
p.2702 (1971)
10 ' Program llsq
20 ' 線形最小自乗法によるカーブフィッティング
30 '
40 DIM X(30),Y(30),YP(30),D(30)
50 ' データの組の数
60 ' X,Yのデータの組
70 READ N
80 FOR I=1 TO N
90 READ X(I),Y(I)
100 NEXT I
110 '
120 SX=0 : SY=0 : SX2=0 : SXY=0 : S5=0
130 FOR I=1 TO N
140 SX = SX + X(I)
150 SY = SY + Y(I)
160 SX2 = SX2 + X(I)^2
170 SXY = SXY + X(I)*Y(I)
180 NEXT I
190 '
200 B = (SY*SX2-SXY*SX)/(N*SX2-SX^2)
210 M = (N*SXY-SX*SY)/(N*SX2-SX^2)
220 FOR I=1 TO N
230 YP(I) = M*X(I) + B
240 D(I) = Y(I) - YP(I)
250 S5 = S5 + D(I)^2
260 NEXT I
270 '
280 SG = SQR(S5/(N-1))
290 X1 = -B/M
300 PRINT N;"点によるフィッティング"
310 PRINT "傾き = ";M
312 PRINT "Y 切片 = ";B
314 PRINT "X 切片 = ";X1
316 PRINT "標準偏差 = ";SG
320 PRINT
330 PRINT " X Y YCALC d"
350 FOR I=1 TO N
360 PRINT X(I), Y(I), YP(I), D(I)
370 NEXT I
400 END
llsq.bas
50 DATA 4
60 DATA .194, -34.2, .590, -31.8, .821, -30, 1.208, -28
解答 温度変化に容器の熱容量を掛けてモル濃度で割れば、1モルあたりの溶解エンタルピーが
求められる。
プログラムllsq.basの該当する行を以下の2行で置き換えて、プログラムを実行する
| 重量モル濃度 |
0.194 |
0.59 |
0.821 |
1.208 |
| 温度変化 (K) |
1.592 |
4.501 |
5.909 |
8.115 |
| 溶解エンタルピー |
34.2 |
31.8 |
30.0 |
28.0 |
問題 p.73 コンピュータプロジェクト 5-3
水素類似系のイオン化エネルギーは、スペクトルデータを利用して、Rydvergの式
から計算することができる。イオン化エネルギーではn1=1、n2=∞であるから、傾きと切片の両方が
Rとなる。
水素原子のLyman系列から取った次の波数(cm-1)のデータからイオン化エネルギーの値を計算せよ。
| n |
1 |
2 |
3 |
4 |
5 |
6 |
| ν |
82259 |
97492 |
102824 |
105292 |
106632 |
107440 |
| 1/(n2^2) |
0.25 |
0.111111111 |
0.0625 |
0.04 |
0.027777778 |
0.020408163 |
プログラムllsq.basの該当する行を以下の3行で置き換えて、プログラムを実行する
50 DATA 6
60 DATA .0.25,82259,0.111111111,97492,0.0625,102824,0.04,105292
65 DATA 0.027777778,106632,0.020408163,107440
得られたRの値を文献値と比較しなさい。
